My never ending problem

[AshTheMonoBear]

So it's been over 3 months now and I can't really say that Garry's Mod is my favorite game anymore. Lots of people have been crashing during their playtime on servers, and they have seem to fix it one way or another. I've tried everything from verifying game caches, reinstalling the game, turning off my firewall (it worked for a day but started crashing the next day), and adding in commands in launch options. I really need an answer. I'm using a Mac so I'm not that surprised that I crash, but apparently windows users are also having the same/similar problem.

My specs are
Mac Air (2015)
1.6 Ghz Intel Core i5
8GB Memory (8 GB Ram) 1600 MHz DD3
Intel HD Graphics 6000 1536MB

Please get back to me ASAP, I don't wanna leave my memories in Garry's Mod behind. Especially since I'm admin on my fav server and now I can't play my role as an admin.

[Hardway245]

What is your Game/Crash log?

[AshTheMonoBear]

I did read my game log and nothing seems to be wrong, it's just a bunch of cannot load skin of player (yadyadyayadyadya) and it doesn't affect me in anyway.

[LexBon321]

Try running the FactoryReset-GMod.bat file in the destination folder.

[AshTheMonoBear]

I'm not sure where that is? Could you maybe provide some steps or at least a photo? I searched for the file on my Mac and found nothing

[Hardway245]

Try verifiyng your Gmod files by steam

[LexBon321]

Go to your steam library, right click Garry's Mod, then go to Properties > Local Files tab > click Browser Local Files, then run the FactoryReset-GMod.bat file.

[AshTheMonoBear]

So a little update, I joined every other kind of server and I don't crash, it's only when I join a type of sandbox server, I don't crash on sandbox servers made by friends though

[joeyjumper]

batch files( files with the .bat) are something that is specific to the windows OS
you might be able to simulate the effects of running FactoryReset-GMod.bat
@echo off

::We don't want people running this in the wrong place
IF NOT EXIST ".\hl2.exe" (
    ECHO Game binary doesn't exist. Are you executing this script from the wrong directory?
    EXIT /B 1
)

::Give the user fair warning
ECHO This script will attempt to reset Garry's Mod to its default state. If the game is running, it will be closed.
ECHO You will lose any settings that have been changed and potentially any saved data, such as duplications.
ECHO Addons will not be removed.
ECHO.

::Let the user bail
CHOICE /N /M "Are you sure you want to continue? [Y/N]"

IF ERRORLEVEL == 2 (
    ECHO Aborting.
    EXIT /B 1
)

ECHO.

::Some of the below won't work if the game is already running
TASKKILL /f /im "hl2.exe" >NUL 2>&1

::Config files
ECHO [1/7] Removing configuration
CALL :DEL_DIR ".\garrysmod\cfg"
CALL :DEL_DIR ".\garrysmod\settings"

::Addon data
ECHO [2/7] Removing stored addon data
CALL :DEL_DIR ".\garrysmod\data"

::Server downloads
ECHO [3/7] Removing downloaded server content
CALL :DEL_DIR ".\garrysmod\download"
CALL :DEL_DIR ".\garrysmod\downloads"
CALL :DEL_DIR ".\garrysmod\downloadlists"

::Gamemodes/Lua
ECHO [4/7] Removing base Lua scripts and gamemodes
CALL :DEL_DIR ".\garrysmod\gamemodes\base"
CALL :DEL_DIR ".\garrysmod\gamemodes\sandbox"
CALL :DEL_DIR ".\garrysmod\gamemodes\terrortown"
CALL :DEL_DIR ".\garrysmod\lua"

::SQLite databases
ECHO [5/7] Removing SQLite databases
CALL :DEL_FILE ".\garrysmod\cl.db"
CALL :DEL_FILE ".\garrysmod\sv.db"
CALL :DEL_FILE ".\garrysmod\mn.db"

::Lua/Workshop cache
ECHO [6/7] Emptying Lua/Workshop cache
CALL :DEL_DIR ".\garrysmod\cache"

::Get steam to redownload anything we've just deleted (this actually also deletes cfg/config.cfg from the Steam Cloud)
ECHO [7/7] Marking game's content for validation by Steam
.\hl2.exe -factoryresetstuff

ECHO.
ECHO Finished. Steam will attempt to download some missing files the next time you launch Garry's Mod.
ECHO.

PAUSE
EXIT /B

:DEL_DIR
    ::ECHO Removing dir %1.
    IF EXIST %1 ( RMDIR /S /Q %1 )
    GOTO:EOF

:DEL_FILE
    ::ECHO Removing file %1.
    IF EXIST %1 ( DEL /Q %1 )
    GOTO:EOF
based on the contents of said file, you need to delete the folders:

"GarrysMod\garrysmod\cfg"
"GarrysMod\garrysmod\settings"
"GarrysMod\garrysmod\data"
"GarrysMod\garrysmod\download"
"GarrysMod\garrysmod\downloads"
"GarrysMod\garrysmod\downloadlists"
"GarrysMod\garrysmod\gamemodes\base"
"GarrysMod\garrysmod\gamemodes\sandbox"
"GarrysMod\garrysmod\gamemodes\terrortown"
"GarrysMod\garrysmod\lua"

and the files:

"GarrysMod\garrysmod\cache"
"GarrysMod\garrysmod\cl.db"
"GarrysMod\garrysmod\sv.db"
"GarrysMod\garrysmod\mn.db"

then go to launch options and put in -factoryresetstuff

[AshTheMonoBear]

Thank you, I might not need it now though because my Garry's Mod is working perfect.